home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / s85xx / s8502b.d64 / listing 6 (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  2KB  |  81 lines
  1. 5 GOSUB60000: REM TABELLEN BESTIMMEN
  2. 10 REM ********* STEUERUNG ***********
  3. 30 GOSUB50000
  4. 40 REM REAGIEREN-AUFRUFEN
  5. 60 REM ******* DEMONSTRATION *********
  6. 62 PRINT:PRINT"BE$ = ";BE$:PRINT
  7. 64 PRINT"VERBZAHL (VE) =";VE
  8. 66 PRINT"1.GEGENSTANDSZAHL (G1) =";G1
  9. 68 PRINT"2.GEGENSTANDSZAHL (G2) =";G2
  10. 70 PRINT"OBJEKTZAHL (OB) =";OB
  11. 72 PRINT"PERSONENZAHL (PE) =";PE
  12. 80 GOTO10
  13. 90 REM *******************************
  14. 50000 REM BEFEHL BE$ VOM SPIELER ERFRAGEN --------------------------------------
  15. 50010 IFUD=1THEN52000
  16. 50020 INPUT"WAS NUN ";BE$
  17. 50030 GOTO51000
  18. 51000 REM BE$ IN BE$(1)-BE$(10) ZERLEGEN----------------------------------------
  19. 51010 FORI=1TO10:BE$(I)="":NEXT
  20. 51020 WZ=1
  21. 51030 FORI=1TOLEN(BE$)
  22. 51040 :IFMID$(BE$,I,1)=" "THENGOSUB51100:GOTO51060
  23. 51045 :IFWZ>10THENPRINT"EINGABE IST ZU LANG !":I=LEN(BE$)+1:GOTO51060
  24. 51050 :BE$(WZ)=BE$(WZ)+MID$(BE$,I,1)
  25. 51060 NEXTI
  26. 51070 GOTO52000
  27. 51100 REM AU$ WOERTER AUSSORTIEREN
  28. 51110 IC=0:FORI1=1TOAZ
  29. 51120 :IFBE$(WZ)=AU$(I1)THENIC=1
  30. 51130 NEXTI1
  31. 51140 IFIC=0THENWZ=WZ+1:RETURN
  32. 51150 BE$(WZ)="":RETURN
  33. 52000 REM DIE BEFEHLSWOERTER UNTERSUCHEN UND DARAUS EINEN SINN DEUTEN ----------
  34. 52005 IFUD=1THENUD=0:GOTO52020
  35. 52010 WZ=1:VE=0:OB=0:PE=0
  36. 52020 IC=0:G1=0:G2=0
  37. 52025 REM *** VERB VE SUCHEN
  38. 52030 FORI=1TOVZ
  39. 52040 :IFBE$(WZ)=VE$(I)THENVE=I:IC=1
  40. 52050 NEXTI:IFIC=1THEN52150
  41. 52060 REM *** GEGENSTAND G1/G2 SUCHEN
  42. 52070 FORI=1TOGZ
  43. 52080 :IFBE$(WZ)<>GE$(I)THEN52090
  44. 52082 : IC=1
  45. 52084 : IFG1=0THENG1=I
  46. 52086 : G2=I:IFG2=G1THENG2=0
  47. 52090 NEXTI:IFIC=1THEN52150
  48. 52100 REM *** OBJEKT OB SUCHEN
  49. 52110 FORI=1TOOZ
  50. 52120 :IFBE$(WZ)=OB$(I)THENOB=I:IC=1
  51. 52130 NEXTI:IFIC=1THEN52150
  52. 52132 REM *** PERSON PE SUCHEN
  53. 52133 FORI=1TOPZ
  54. 52134 :IFBE$(WZ)=PE$(I)THENPE=I:IC=1
  55. 52135 NEXTI:IFIC=1THEN52150
  56. 52137 IFBE$(WZ)="UND"THENUD=1:IC=1
  57. 52140 IFIC=0THENPRINT"ICH KENNE ";BE$(WZ);" NICHT !":RETURN
  58. 52150 WZ=WZ+1
  59. 52160 IFWZ>10ORBE$(WZ)=""ORUD=1THENRETURN
  60. 52170 IC=0:GOTO52025
  61. 60000 REM *****************************
  62. 60001 REM * W O R T - T A B E L L E N *
  63. 60002 REM *****************************
  64. 60010 REM *** AU$-WORT-TABELLE
  65. 60020 DATA DER,DIE,DAS,DEN, ,UEBER,UNTER,AUF,IN,VON,VOM,IM,NACH,DURCH,MIT,DEM
  66. 60022 DATA AM
  67. 60030 AZ=17:DIMAU$(AZ):FORI=1TOAZ:READAU$(I):NEXT
  68. 60050 REM *** VERB-TABELLE VE$
  69. 60060 DATA NIMM,VERLIERE,OEFFNE,GIB,SAGE,INVENTUR,BEFESTIGE
  70. 60070 VZ=7:DIMVE$(VZ):FORI=1TOVZ:READVE$(I):NEXT
  71. 60090 REM *** GEGENSTANDS-TABELLE GE$
  72. 60100 DATA SCHWERT,SCHLUESSEL,SEIL,FACKEL,ARMBRUST,HELM,SCHILD
  73. 60110 GZ=7:DIMGE$(7):FORI=1TOGZ:READGE$(I):NEXT
  74. 60130 REM *** OBJEKT-TABELLE OB$
  75. 60140 DATA FENSTER,TUER,TRUHE,KISTE,FALLTUER
  76. 60150 OZ=5:DIMOB$(OZ):FORI=1TOOZ:READOB$(I):NEXT
  77. 60160 REM *** PERSONEN-TABELLE PE$
  78. 60170 DATA GEIST,MONSTER,THORIN,GOMMEL,ORK
  79. 60180 PZ=5:DIMPE$(PZ):FORI=1TOPZ:READPE$(I):NEXT
  80. 60200 RETURN
  81.